home *** CD-ROM | disk | FTP | other *** search
/ 64'er / 64ER_CD.iso / s85xx / s8504a.d64 / basic druck (.txt) < prev    next >
Commodore BASIC  |  1995-03-30  |  1KB  |  43 lines
  1. 100 REM  BASICVERSION DER DRUCKROUTINE
  2. 110 REM  KANN AUCH ALS UNTERROUTINE IN EIGENE PROGRAMME EINGEBAUT WERDEN
  3. 120 REM  ANPASSUNG AN ANDERE 7-NADEL-DRUCKER SICHER MOEGLICH
  4. 130 OPEN4,4:OPEN6,4,6:PRINT#6,CHR$(16):CLOSE6:POKE56,30
  5. 140 REM  OFFNET DRUCKKANAL UND STELLT ZEILENABSTANT FUER GRAFIK EIN
  6. 150 FOR I=319 TO-3 STEP -7
  7. 160 U$="":U2$="":O$="":O2$=""
  8. 170 FOR Y=0 TO199:C=128:G=128
  9. 180 FOR X=I TO I-2 STEP -1
  10. 190 A=0:GOSUB1000
  11. 200 BI=2*(I-X)
  12. 210 IFA=1THEN C=C+2^BI+2^(BI+1)
  13. 220 NEXTX
  14. 230 A=0:X=I-3:GOSUB1000
  15. 240 IF A=1THEN C=C+64 :G=G+1
  16. 250 FOR X=I-4 TO I-6 STEP -1
  17. 260 A=0:GOSUB1000
  18. 270 BI =2*(I-X-4)
  19. 280 IF A=1 THEN G=G+2^(BI+1)+2^(BI+2)
  20. 290 NEXTX
  21. 300 IF Y<100THENO$=O$+CHR$(C)+CHR$(C)
  22. 310 IF Y>99THENO2$=O2$+CHR$(C)+CHR$(C)
  23. 320 IF Y<100THENU$=U$+CHR$(G)+CHR$(G)
  24. 330 IF Y>99THENU2$=U2$+CHR$(G)+CHR$(G)
  25. 340 NEXTY
  26. 350 PRINT#4,CHR$(8)CHR$(27)CHR$(16)CHR$(0)CHR$(40);
  27. 360 PRINT#4,O$O2$CHR$(9)
  28. 370 REM  CHR$(8) STELLT BIT-MUSTER-MODUS EIN
  29. 380 REM  CHR$(27)CHR$(16)CHR$(0)CHR$(40) STELLT DIE DRUCKSTARTADRSSE JEDER
  30. 390 REM  ZEILE AUF 40 PUNKTE NACH RECHTS EIN
  31. 400 REM CHR$(9) STELLT DEN BIT-MUSTER-MODUS WIEDER AUS
  32. 410 PRINT#4,CHR$(8)CHR$(27)CHR$(16)CHR$(0)CHR$(40);
  33. 420 PRINT#4,U$U2$CHR$(9)
  34. 430 NEXTI
  35. 440 CLOSE4:END
  36. 450 REM  PRUEFROUTINE OB DER GRAFIKPUNKT GESETZT ODER NICHT GESETZT IST:
  37. 1000 IFX<0THENA=0:RETURN
  38. 1010 BY=(XAND504)+40*(YAND248)+(YAND7)
  39. 1020 BI=2^(7-(XAND7))
  40. 1030 S=PEEK(8192+BY)
  41. 1040 IF(SORBI)=STHENA=1
  42. 1050 RETURN
  43.